MultiLineEdit with Search Forward/Backward

The MultiLineEdit control is useful for both user input, and when set readonly, for displaying text documentation.

I needed to add a search box, where you could enter text and pres Previous or Next buttons to find the next occurance of the text.

My solution also shows the count of number of occurances, and signals when at the start (for Previous button) or end (for Next button) of the text.

You will need an Edit control (edSearch), two buttons (btPrev and btNext) and a label (lbFound) to hold the resulting count.

I also add a private array of integers (searchlist) which holds the offset of each occurance of the search string.

First: loading the data

You can load the data by setting MultiLineEdit.Lines.Text to a string from your web site.

On many browsers this will scroll to the bottom of the text, so set it back to the top with:

   MultiLineEdit1.SelectionStart := 0;
   MultiLineEdit1.SelectionEnd := 0;
   MutliLineEdit1.SetFocus;

The SetFocus is necessary to bring the MultiLineEdit into focus.

How Carets Work

MultiLineEdit stores lines of text as a TStrings, which you can access as list of lines, or you can specify .Text and get the complete string.

Internally, the web browser deals with the data as one long string (like the .Text data) but where each end of line is one character (not 2, not CR LF you may be expecting).

When you set MultiLineEdit’s SelectionStart to 25, it points to the 25th caracter of the string, on whichever line it is on. And selection end is set to that same position + the length of the selected string.

We will use Pos() to search the data string for each occurance. But before searching it we need to use strreplace() to remove the line feeds to accurately reference the data or EWB will add one offset per line. We also need to subtract one because EWB strings are offset starting at 1 while JavaScript strings start at 0.

We will build a list of indices stored in searchlist

So here’s the first bit of code:

procedure TFormShowText.getsearchlist( s : string );
var
   pre : integer;
   count : integer;
   text : string;
begin
//   MultiLineEdit1.selectnone;
   pre := 1;
   count := 0;
   setlength( searchlist, 0 );
   // compare case insenstively
   s := lowercase( s );
   text := LowerCase( strreplace( MultiLineEdit1.Lines.Text, #10, '',True ));
   repeat
      pre := pos( s, text , pre);
      if pre > 0 then begin
         searchlist[count] := pre - 1; // offset of 1 in pascal string
         inc( count );
         inc(pre, length(s )); // advance it to next word
      end;
   until pre < 1;
   lbfound.caption := IntToStr( count) + ' occurances found';
end;

Next Button

Here’s the code for the Next button, it searches for where we are in the file and chooses the next occurance.

procedure TFormShowText.btNextClick(Sender: TObject);
var
  x, i : integer;
  cur : integer;
begin
  getsearchlist( edSearch.Text );
  cur := MultiLineEdit1.SelectioNStart;

  for i := 0 to Length( searchlist) -1 do begin

     if searchlist[i] > cur then begin
         x := searchlist[i];
          multilineEdit1.SetFocus;
         multilineedit1.SelectionStart := x;
         multilineedit1.SelectionEnd := x + length( edSearch.Text );
         multilineedit1.SetFocus; // needed
         scrolltoline( x );
         exit;
     end;

  end;
  showmessage('End of file');
end;

Scrolling Problem

The above code calls ScollToLine( position ), that’s not a built-in routing. The problem I had to solve was to get the scrolling right so the selected text is focused.

So we set the MultiLineEdit scrolltop to the right number of pixels down from the top. But how do you find it.

The first step is to find the line number. I wrote GetLineNumber() which uses a temporary TStringList to convert the subset of text into a series of lines, and just return the count.

function getLineNumber( txt : string ; ofs : integer ):integer;
var
  sl : tstringlist;
begin
  sl := TStringList.Create;
  sl.text := copy( txt, 1, ofs );
  result := sl.Count-1;  // subtract one because we want the previous line

  sl.Free;
end;

Then we use ScrollToLine below to scroll to that line number. We can do that because we know there are MultiLineEdit.font.size pixels in the font, and about two extra spacing pixels separating each line. It’s not perfect, but usually pretty close.

procedure TFormShowText.scrolltoline( ofs : integer );
var
  linenum : integer;
  pixels : integer;
  txt : string;
begin

  linenum := getLineNumber( MultiLineEdit1.Lines.Text, ofs );
  pixels := linenum * (2+MultilineEdit1.font.size);

  MultiLineEdit1.ScrollTop := pixels;
end;

The Prev Button

And here’s the code for the previous button.

procedure TFormShowText.btPreviousClick(Sender: TObject);
var
  i, x , cur :integer;
begin
  getsearchlist( edSearch.Text );
  cur := MultiLineEdit1.SelectioNStart;
  for i := 0 to Length( searchlist) -1 do begin

     if searchlist[i] >= cur then
        if i > 0 then begin
           x := searchlist[i-1];
           multilineEdit1.SetFocus;
           multilineedit1.SelectionStart := x;
           multilineedit1.SelectionEnd := x + length( edSearch.Text );
           multilineedit1.SetFocus;
           scrolltoline( x );
           break;
        end else
           Showmessage('Beginning of file');
  end;
end;

That’s all there is to it.